home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magnum One
/
Magnum One (Mid-American Digital) (Disc Manufacturing).iso
/
d3
/
allmac21.arc
/
GETCOM11.ARC
/
GETCOM11.QM
< prev
next >
Wrap
Text File
|
1990-08-27
|
16KB
|
331 lines
* Macro To Get Command & Key From QCONFIG.DAT, v1.1a
* GETCOM11.QM
*
* @0 gets a single command and it's key on screen, then removes
* @1 puts command key beside ALL commands in a macro |
* @2 puts command key beside a single command in a macro |new v1.1
* @3 makes single column of commands in macro (from COLUMN10) |
* Version History:
*
* 1.0a - modified Alt_0 to find all multiple commands matching
* the search criteria.
* 1.1 - added Alt_1/2/3.
* 1.1a - changed documentation and Alt_3 from COLUMN10.
* In order for these macros to find a command in QCONFIG.DAT, there must
* be at least four blank spaces betweeen the end of the command key and
* the beginning of the command. If your QCONFIG.DAT has fewer spaces, the
* macros must be modified in the first 'find' line.
*
*
*
*
* Before running, be sure to change the lines with ** below to the
* location of your qconfig.dat. Insert must be ON.
* To run:
*
* 1. First, you must make a single column macro with Alt_3. To do this,
* place the cursor line anywhere in a macro txtfile (after loading the
* macfile) and press Alt and 3 at the same time.
*
* 2. To find the keys for ALL commands in a macro, place the cursor
* line at the topof a macro txtfile and press Alt_1. An example of this
* output is shown at the end of this file. The keys corresponding to
* each command will be listed also in a single column next to the
* command.
*
* 3. To find the key for a single command in a macro, place the cursor
* line on the command in a macro txtfile and press Alt_2. The key
* corresponding to the command will be listed next to the commmand.
*
*
*
*
* ┌─────────────────────────────────────────────────────────┐
* │ @0 Retrieves a command and it's key from QCONFIG.DAT │
* └─────────────────────────────────────────────────────────┘
* This macro retrieves a command or all commands matching a selected
* find criteria from your QCONFIG.DAT file, displays the selected
* command(s) and it's key on the screen, and then removes the
* command(s) and it's key from the screen. For those of us who can
* never remember all the commands and can never find our reference
* sheet, this might help.
*
* First, be sure to change "g:\qe\qconfig.dat" in the macro below to
* the location of your qconfig.dat in your setup, and convert.
*
* To run, press Alt_0, then enter the first letter (or more) of the
* command you want to know the key for, press 'Enter' to see the the
* command(s) and it's key, then press 'Enter' again to remove the
* command(s) and it's key from the screen.
*
* For example, to find the key for appendscrbuff, press:
* Alt_0
* "app" (no quotes)
* Enter
*
* You should see the following highlighted on your screeen:
* |
* ^b_a appendscrbuff |
* Entering "b" instead shows all commands beginning with "b":
* |
* ^h backspace |
* ^home begscreen |
* ^pgup begfile |
* home begline |
* backspace backspace |
* Press 'Enter' to remove the command(s) and it's key from the screen,
* or press 'Esc' three times if you want to keep the command(s) on the
* screen for reference.
*
@0 macrobegin
unmarkblock * unmarkblock
insertline * insert blank line
markcolumn * markcolumn
currentfilename * get currentfilename
copy * get filename to scrap
delline * delline after
editfile *
"g:\qe\qconfig.dat" ** CHANGE for your setup **
return * load qconfig.dat
dropanchor * start to clear scrap
storescrbuff "1" return * get to scrap
unmarkblock * get ready to find and mark
begfile * go to begin qconfig.dat
find " " * insert 4 spaces before find
pause * pause for command to find
return "i" return * find first command
jump NEXT: *
START: * come here more than 1 find
find * find next command
return "i" return *
NEXT: *
jfalse FINISH: * mark if found, quit if not
markline * mark command line
begline * put at begline
"* " * asterisk space
appendscrbuff "1" return * get to scrbuff
cursordown * move down line
unmarkblock * unmark command
jump START: * see if any more matches
FINISH: * come here after last find
quit * quit qconfig.dat
editfile paste return * return to file
markcolumn * start to mark block
getscrbuff "1" return * get command and key
begline * get to block begin
makectrofscreen * for better viewing
pause * pause, then 'Enter' to..
makectrofscreen * back to where we were
deleteblock * clean up, remove block
*
* 107 bytes Wed 08-22-1990 21:08:33
*┌────────────────────────────────────────────────────┐
*│ @1 Puts key beside ALL commands in single column │
*└────────────────────────────────────────────────────┘
* Does all commands in a macro txtfile
*
@1 macrobegin
unmarkblock * unmarkblock
insertline * insert blank line
markcolumn * markcolumn
currentfilename * get currentfilename
storescrbuff "1" return * get to scrbuff
delline * delline after
START: *
endline begline * line blank? if so end
jfalse END: *
begline * go to begin line
wordright * get to command
markword * mark it
copy * get to scrap
unmarkblock * unmark
editfile *
"g:\qe\qconfig.dat" ** CHANGE for your setup **
return * load qconfig.dat
begfile * go to begin qconfig.dat
FIND " " * insert 4 spaces before find
paste * paste command for find
return "IW" return * find command in qconfig.dat
jfalse NOFIND: * mark if found, quit if not
wordright * move cursor to command
markcolumn * markcolumn
begline * go to begline
"* " * insert asterisk space
begline * go to begline
markcolumn * finish marking key
storescrbuff "2" return * get key to scrbuff 1
cursordown * move down line
unmarkblock * unmark command
quit * quit qconfig.dat
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * load currentfilename
markcolumn * start to mark block
gotocolumn "33" return * postition to get key
getscrbuff "2" return * get key
begline * go to begline
makectrofscreen * for better viewing
cursordown * move down to next command
jump START: * start on next command
NOFIND: * come here if no key for command
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * return to file
gotocolumn "33" return * position to get key
"* " * insert asterisk space
cursordown * move down to next command
begline *
jump START: * do next line till done
END: *
*
* 143 bytes Wed 08-22-1990 21:08:49
*┌───────────────────────────────────────────────────────────┐
*│ @2 Puts key beside command with commands in single column │
*└───────────────────────────────────────────────────────────┘
* Does single commands only
*
@2 macrobegin
unmarkblock * unmarkblock
insertline * insert blank line
markcolumn * markcolumn
currentfilename * get currentfilename
storescrbuff "1" return * get to scrbuff
delline * delline after
begline * go to begin line
wordright * get to command
markword * mark it
copy * get to scrap
unmarkblock * unmark
editfile *
"g:\qe\qconfig.dat" ** CHANGE for your setup **
return * load qconfig.dat
begfile * go to begin qconfig.dat
FIND " " * insert 4 spaces before find
paste * paste command for find
return "IW" return * find command in qconfig.dat
jfalse NOFIND: * mark if found, quit if not
wordright * move cursor to command
markcolumn * markcolumn
begline * go to begline
"* " * insert asterisk space
begline * go to begline
markcolumn * finish marking key
storescrbuff "2" return * get key to scrbuff
cursordown * move down line
unmarkblock * unmark command
quit * quit qconfig.dat
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * load currentfilename
markcolumn * start to mark block
gotocolumn "33" return * postition to get key
getscrbuff "2" return * get key
begline * go to begline
makectrofscreen * for better viewing
cursordown * move down to next command
jump END: * stop after getting key
NOFIND: * come here if no key for command
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * return to file
gotocolumn "33" return * position to get key
"* " * insert asterisk space
cursordown * move down to next command
begline *
END: *
*
* 135 bytes Wed 08-22-1990 21:09:01
*┌────────────────────────────────────────────────────────┐
*│@3 Makes single column txtfile from any txtfile │
*│ Uses batch files QMACB.BAT and QMACT-N.BAT │
*└────────────────────────────────────────────────────────┘
* Macro from COLUMN10.ZIP
*
@3 macrobegin
writeblock "c:$.qm" * copy block or file to c:$.qm
return return *
***************************************** GET CURRENTFILENAME TO SCRAP
insertline * insert blank line
begline *
dropanchor * start mark
currentfilename * get currentfilename
storescrbuff "1" return * to scrbuff 1
cut * to scrap
*****************************************
dos "qmacb c:$" return return * make macfile
dos "qmact-n c:$" return return * make txtfile
editfile "c:$.qm" return quit *
editfile return * load c:$.qm
endfile return * insert blank line at end
"*" insertdate inserttime * for date/time
getscrbuff "1" return * and file name
unmarkblock *
savefile * save c:$.qm
*
* 103 bytes Sun 08-05-1990 17:50:06
* 103 bytes Thu 08-23-1990 14:30:14
* The following (with star and space added) is the output from first
* running Alt_3, then Alt_1 on the single column macro Alt_3 above.
*
* @3 MacroBegin *
* WriteBlock * @w
* "c:$." *
* "qm" *
* Return * enter
* Return * enter
* InsertLine * ^n_i
* BegLine * home
* DropAnchor * @a
* CurrentFilename * ^n_n
* StoreScrbuff * ^b_s
* "1" *
* Return * enter
* Cut * ^c_u
* Dos "" * ^n_o
* "qmacb " *
* "c:$" *
* Return * enter
* Return * enter
* Dos "" * ^n_o
* "qmact-" *
* "n c:$" *
* Return * enter
* Return * enter
* EditFile * f3
* "c:$." *
* "qm" *
* Return * enter
* Quit * @x
* EditFile * f3
* Return * enter
* EndFile * ^pgdn
* Return * enter
* "*"
* InsertDate * ^d
* InsertTime * ^e
* GetScrbuff * ^b_g
* "1" *
* Return * enter
* UnmarkBlock * @u
* SaveFile * f2
*
* Tom Hogshead Thu 08-23-1990 14:32:48